Check video demonstration of issue https://youtu.be/fzPZh_sHKAA (Listener - a player client outside the plane. Sound source - a plane with a player pilot)

See code in path CfgVehicles → Plane_Fighter_01_Base_F → UserActions:

1. "Plane_Fighter_01_tailhook_down"

...
this say 'Plane_Fighter_01_tailhook_down_sound';
this say3D 'Plane_Fighter_01_tailhook_down_sound';
...

1. Sound played with say command seems used to play sound in 2D for pilot, but say plays 3D sound, this produce duplication sound play together with say3D.

2. Second issue can be reproed in multiplayer, class UserActions run code in local on machine who use action, say3D is global-argument / local-effect, this couse sound won't work in multiplayer session for other players.

   Suggest fix, change existed code from to:

   [
       [this],
       {
           params ['_veh'];
           if (player in _veh) then
           {
               playSound 'Plane_Fighter_01_tailhook_down_sound'
           }
           else
           {
               _veh say3D ['Plane_Fighter_01_tailhook_down_sound', 100, 1, 0, 0, false];
           };
       }
   ] remoteExec ['spawn', 0];

   playSound will play to crew it's 2D sound, say3D will successfully play sound for other players (e.g. on land)

2. "Plane_Fighter_01_tailhook_up"

same problem as above but different CfgSounds class

//from this
this say 'Plane_Fighter_01_tailhook_up_sound';
this say3D 'Plane_Fighter_01_tailhook_up_sound'

//to this ↓↓↓
[
    [this],
    {
        params ['_veh'];
        if (player in _veh) then
        {
            playSound 'Plane_Fighter_01_tailhook_up_sound'
        }
        else
        {
            _veh say3D ['Plane_Fighter_01_tailhook_up_sound', 100, 1, 0, 0, false];
        };
    }
] remoteExec ['spawn', 0];

3. "Plane_Fighter_01_fold_wings"

...
this say3D 'Plane_Fighter_01_foldwing_sound'

1. Sound inaudible in multiplayer (for player not in vehicle)

2. CfgSounds parameters does not match. Please check sounds parameter in: CfgSounds → Plane_Fighter_01_foldwing_sound max hearing distance defined with 1100 value (meters). I don't know should wing fold sound be heard in 1 km or no, but if you would like to fix it you need write parameters when executing say3D command, reason: if CfgSounds defined 1100 meters sound hearable, but you execute like _this say3D 'MySound'; max hear range will be reset to 100 meters as noted on BIKI

   Suggest fix, change to:

   [this, ['Plane_Fighter_01_foldwing_sound', 150, 1, 0, 0, false]] remoteExecCall ['say3D'];

   150 - is my suggested max hearing range value

4. "Plane_Fighter_01_unfold_wings"

Absolutely the same problem noted above in "Plane_Fighter_01_fold_wings", the fix will look the same as described:

[this, ['Plane_Fighter_01_foldwing_sound', 150, 1, 0, 0, false]] remoteExecCall ['say3D'];

Next, see full config patch to fix issues:

class CfgVehicles
{
	class Plane_Base_F;
	class Plane_Fighter_01_Base_F: Plane_Base_F
	{
		class UserActions
		{
			class Plane_Fighter_01_Eject;
			class Plane_Fighter_01_tailhook_down: Plane_Fighter_01_Eject
			{
				statement="this animate ['tailhook',0]; this animate ['tailhook_door_l',0]; this animate ['tailhook_door_r',0]; this SetUserMFDvalue [4,1]; [this] spawn BIS_fnc_AircraftTailhook;  [ [this], { params ['_veh']; if (player in _veh) then { playSound 'Plane_Fighter_01_tailhook_down_sound'} else { _veh say3D ['Plane_Fighter_01_tailhook_down_sound', 100, 1, 0, 0, false]; }; }] remoteExec ['spawn', 0];";
			};
			class Plane_Fighter_01_tailhook_up: Plane_Fighter_01_tailhook_down
			{
				statement="this animate ['tailhook',1]; this animate ['tailhook_door_l',1]; this animate ['tailhook_door_r',1]; this SetUserMFDvalue [4,0]; [ [this], { params ['_veh']; if (player in _veh) then { playSound 'Plane_Fighter_01_tailhook_up_sound'; } else { _veh say3D ['Plane_Fighter_01_tailhook_up_sound', 100, 1, 0, 0, false]; }; } ] remoteExec ['spawn', 0];";
			};
			class Plane_Fighter_01_fold_wings: Plane_Fighter_01_Eject
			{
				statement="this animate ['wing_fold_l',1]; this animate ['wing_fold_r',1]; this animate ['wing_fold_cover_l',1]; this animate ['wing_fold_cover_r',1]; [this, ['Plane_Fighter_01_foldwing_sound', 150, 1, 0, 0, false]] remoteExecCall ['say3D'];";
			};
			class Plane_Fighter_01_unfold_wings: Plane_Fighter_01_fold_wings
			{
				statement="this animate ['wing_fold_l',0]; this animate ['wing_fold_r',0]; this animate ['wing_fold_cover_l',0]; this animate ['wing_fold_cover_r',0]; [this, ['Plane_Fighter_01_foldwing_sound', 150, 1, 0, 0, false]] remoteExecCall ['say3D'];";
			};
		};
	};
};